Rexx

This article is about classic Rexx. For oRexx and ooRexx, see Object Rexx.

Rexx

Paradigm	multiparadigm: procedural, structured
Designed by	Mike Cowlishaw
Developer	Mike Cowlishaw, IBM
First appeared	1979 (1979)
Stable release	ANSI X3.274 / 1996 (1996)
Typing discipline	Dynamic
Filename extensions	.cmd, .bat, .exec, .rexx, .rex, EXEC
Major implementations
VM/SP R3, TSO/E V2, SAAREXX, ARexx, BREXX, Regina, Personal REXX, REXX/imc
Dialects
NetRexx, Object REXX, now ooREXX, KEXX
Influenced by
PL/I, ALGOL, EXEC, EXEC 2
Influenced
NetRexx, Object REXX
Rexx Programming at Wikibooks

Rexx (Restructured Extended Executor) is a high-level programming language developed at IBM by Mike Cowlishaw. Both proprietary and open source Rexx interpreters exist for a wide range of computing platforms, and compilers exist for IBM mainframe computers. Rexx is used for scripting, application macros and application development. As a general purpose scripting language, Rexx is considered a precursor to Tcl and Python.

Rexx is supported in a variety of environments. It is the primary scripting language in some operating systems including OS/2, MVS, VM, AmigaOS and is used for macros in some software including SPF/PC, KEDIT, THE and ZOC. With an engine installed, Rexx can be used for scripting and macros in programs that use a Windows Scripting Host ActiveX scripting engine (such as VBScript or JScript). Rexx is supplied with VM/SP Release 3 on up, TSO/E Version 2 on up, OS/2 (1.3 and later, where it is officially named Procedures Language/2), AmigaOS Version 2 on up, PC DOS (7.0 or 2000), ArcaOS, and Windows NT 4.0 (Resource Kit: Regina). In the late 1980s, Rexx became the common scripting language for IBM Systems Application Architecture, where it was renamed "SAA Procedure Language REXX".

A script is associated with a Rexx interpreter at runtime in various ways based on context. In mainframe computing, a Rexx script or command is sometimes referred to as an EXEC since that is the name of the file type used for similar CMS EXEC, and EXEC 2 scripts and for Rexx scripts on VM/SP R3 through z/VM. The first line of a script specifies the use of a Rexx interpreter in a comment either by identifying the code as Rexx language or by file path via EXTPROC. On MVS, Rexx scripts may be recognized by the low level qualifier "EXEC" or if the first line fetched from SYSPROC is a comment containing "REXX" then it is treated as Rexx (rather than CLIST), and a script fetched from SYSEXEC must be Rexx. On OS/2, Rexx scripts share the filename extension ".cmd" with other scripting languages, and the first line of the script specifies the interpreter to use. On Linux, Rexx scripts generally begin with a shebang. Rexx macros for Rexx-aware applications use extensions determined by the application.

Name

Originally, the language was called REX, short for Reformed Executor, but an extra "X" was added to avoid confusion with other products. The name was originally all uppercase because that was the only way to represent it in mainframe code at the time. Both editions of Mike Cowlishaw's first book on the language use all-caps, REXX, although the cover graphic uses mixed case. His book on NetRexx uses mixed case but all caps in the cover graphic with large and small caps, NETREXX. An expansion that matches the abbreviation, REstructured eXtended eXecutor, was used for the system product in 1984. The name Rexx (mixed case) is used in this article, and is commonly used elsewhere.

Attributes

Objective and subjective attributes of Rexx include:

• Simple syntax
• Ability to route commands to multiple environments
• Ability to support functions, procedures and commands associated with a specific invoking environment.
• Built-in stack with the ability to interoperate with the host stack if there is one
• Small instruction set
• Free-form syntax; indentation is optional but can help readability
• Case-insensitive tokens, including variable names
• Character string basis
• Dynamic data typing; no declarations
• No reserved keywords, except in local context
• No include file facility
• Arbitrary-precision arithmetic
• Decimal arithmetic, floating-point
• Rich selection of built-in functions, especially string and word processing
• Automatic storage management
• Crash protection
• Content addressable data structures
• Associative array
• Straightforward access to system commands and facilities
• Simple error-handling, and built-in tracing and debugger
• Few artificial limitations
• Simplified I/O facilities
• Unconventional operators
• Only partly supports Unix style command line parameters, except specific implementations
• Provides no basic terminal control as part of the language, except specific implementations
• Provides no generic way to include functions and subroutines from external libraries, except specific implementations

Some claim that Rexx is a relatively simple language. With only 23 instructions (such as call, parse, and select), it has a relatively small instruction set. Rexx has limited punctuation and formatting requirements. Rexx has only one data type, the character string. Some claim that such simplicities make Rexx relatively easy to debug.

Some claim that Rexx code looks similar to PL/I code, but has fewer notations. With fewer notations, it tends to be is harder to parse via a translator, but is easier to write. Simplifying coding was intentional as noted by the Rexx design goal of the principle of least astonishment.

History

pre–1990

On his own time, Mike Cowlishaw developed the language and an interpreter for it in assembly language between 20 March 1979 and mid-1982 with the intent to replace the languages EXEC and EXEC 2. Mike also intended Rexx to be a simplified and easier to learn version of PL/I, but some claim that Rexx has problematic differences from PL/I.

Rexx was first described in public at the SHARE 56 conference in Houston, Texas, in 1981, where customer reaction, championed by Ted Johnston of SLAC, led to it being shipped as an IBM product in 1982.

Over the years IBM included Rexx in almost all of its operating systems (VM/CMS, MVS TSO/E, IBM OS/400, VSE/ESA, AIX, PC DOS, and OS/2), and has made versions available for Novell NetWare, Windows, Java, and Linux.

The first non-IBM version was written for PC DOS by Charles Daney in 1984/5 and marketed by the Mansfield Software Group (founded by Kevin J. Kearney in 1986). The first Rexx compiler appeared in 1987, written for CMS by Lundin and Woodruff. Other versions have also been developed for Atari, AmigaOS, Unix (many variants), Solaris, DEC, Windows, Windows CE, Pocket PC, DOS, Palm OS, QNX, OS/2, Linux, BeOS, EPOC32/Symbian, AtheOS, OpenVMS, Apple Macintosh, and Mac OS X.

ARexx, a Rexx interpreter for Amiga, was included with AmigaOS 2 onwards and was popular for scripting and application control. Many Amiga applications have an "ARexx port" which allows control of the application via a Rexx script. Notably, a Rexx script can switch between Rexx ports to control multiple applications.

1990 to present

In 1990, Cathie Dager of SLAC organized the first independent Rexx symposium, which led to the forming of the Rexx Language Association. Symposia are held annually.

Several freeware versions of Rexx are available. In 1992, the two most widely used open-source ports appeared: Ian Collier's REXX/imc for Unix and Anders Christensen's Regina (later adopted by Mark Hessling) for Windows and Unix. BREXX is well known for WinCE and Pocket PC platforms, and has been "back-ported" to VM/370 and MVS.

OS/2 has a visual development system from Watcom VX-REXX. Another dialect was VisPro REXX from Hockware.

Portable Rexx by Kilowatt and Personal Rexx by Quercus are two Rexx interpreters designed for DOS and can be run under Windows as well using a command prompt. Since the mid-1990s, two newer variants of Rexx have appeared:

• NetRexx: compiles to Java byte-code via Java source code; this has no reserved keywords at all, and uses the Java object model, and is therefore not generally upwards-compatible with 'classic' Rexx.
• Object REXX: an object-oriented generally upwards-compatible version of Rexx.

In 1996 American National Standards Institute (ANSI) published a standard for Rexx: ANSI X3.274–1996 "Information Technology – Programming Language REXX". More than two dozen books on Rexx have been published since 1985.

Rexx marked its 25th anniversary on 20 March 2004, which was celebrated at the Rexx Language Association's 15th International REXX Symposium in Böblingen, Germany, in May 2004.

On October 12, 2004, IBM announced their plan to release their Object REXX implementation's sources under the Common Public License. Recent releases of Object REXX contain an ActiveX Windows Scripting Host (WSH) scripting engine implementing this version of the Rexx language.

On February 22, 2005, the first public release of Open Object Rexx (ooRexx) was announced. This product contains a WSH scripting engine which allows for programming of the Windows operating system and applications with Rexx in the same fashion in which Visual Basic and JScript are implemented by the default WSH installation and Perl, Tcl, Python third-party scripting engines.

As of January 2017 Rexx was listed in the TIOBE index as one of the fifty languages in its top 100 not belonging to the top 50.

In 2019, the 30th Rexx Language Association Symposium marked the 40th anniversary of Rexx. The symposium was held in Hursley, England, where Rexx was first designed and implemented.

Toolkits

RexxUtil – a package of file and directory functions, windowed I/O, and functions to access system services such as WAIT and POST – is available for most Rexx environments.

Rexx/Tk – a toolkit for graphics to be used in Rexx programmes in the same fashion as Tcl/Tk – is widely available.

RxxxEd – an integrated development environment (IDE) for Rexx – was developed for Windows. RxSock for network communication as well as other add-ons to and implementations of Regina Rexx have been developed, and a Rexx interpreter for the Windows command line is supplied in most resource kits for various versions of Windows and works in DOS as well.

Syntax

Types of statement

Rexx has three types of statement

Assignment statement

Evauate an expression and assign its value to a simple or compound variable

Expression

Evaluate the expression and treat the value as a command in the default environment

address foo /* set default environment for bare expression */
bar /* equivalent to address foo bar */

Keyword instruction

Begins with a specific word

Looping

The language provides loop control similar to many other languages. A loop begins with do and ends with end. In the related NetRexx, the keyword loop is used instead of do, and ooRexx treats loop and do the same.

A loop is aborted (early exit) via leave and short-circuited (continued) via iterate.

Conditional loop

The language supports testing a condition either before (do while) or after (do until) executing a block of code.

do while [condition]
  [instructions]
end

do until [condition]
  [instructions]
end

Repetitive loop

A loop can increment a variable and stop when a limit is reached.

do index = start [to limit] [by increment] [for count]
  [instructions]
end

The increment value is 1 if the by clause is omitted. The loop continues forever if the limit to clause is omitted.

The language permits counted loops, where an expression is computed at the start of the loop and the instructions within the loop are executed that many times:

do expression
  [instructions]
end

The language supports an unconditional loop via forever that continues until the loop is aborted or the program is terminated.

do forever
  [instructions]
end

Combined loop

Like PL/I, Rexx allows both conditional and repetitive elements to be combined in the same loop:

do index = start [to limit] [by increment] [for count] [while condition]
  [instructions]
end

do expression [until condition]
  [instructions]
end

Conditional

The language provides for conditional execution via if, then and else for a block delimited by do and end.

if [condition] then
  do
  [instructions]
  end
else
  do
  [instructions]
  end

For a single instruction block, do and end can be omitted.

if [condition] then
  [instruction]
else
  [instruction]

Multiple condition branching

The language provides multiple condition branching via select which derives from the SELECT; form of the PL/I SELECT statement . Like similar constructs in other dynamic languages, Rexx's when clauses specify full conditions – not equality tests of a single value for the statement as some languages do. In that, they are more like cascading if-then-else code than like the C or Java switch statement.

select
  when [condition] then
    [instruction] or NOP
  when [condition] then
    do
    [instructions] or NOP
    end
  otherwise
    [instructions] or NOP
end

The NOP instruction is required if no action is associatd with a when condition.

The otherwise clause is optional. If omitted and no when conditions are met, then the SYNTAX condition is raised.

Variable

Typing system

Variables are typeless and initially are evaluated as their names in upper case. Thus a variable's type can vary with its use in the program:

say hello /* => HELLO */
hello = 25
say hello /* => 25 */
hello = "say 5 + 3"
say hello /* => say 5 + 3 */
interpret hello /* => 8 */
drop hello
say hello /* => HELLO */

Evaluation

If no NOVALUE condition handler is configured, then an undefined variable evaluates to its name, in upper case. The built-in function SYMBOL returns "VAR" for a defined variable and does not trigger NOVALUE even if not defined. The VALUE function gets the value of a variable without triggering a NOVALUE condition, but its main purpose is to read and set environment variables, similar to POSIX getenv and putenv.

Compound variable

The language provides the compound variable construct which supports adding fields (called tails) to a variable (called a stem in this context) to support data structures such as lists, arrays, n-dimensional arrays, sparse or dense arrays, balanced or unbalanced trees and records.

The language does not provide special support for numeric array indexing like many other languages do. Instead, a compound variable with numeric tails produce a similar effect.

The following code defines variables stem.1 = 9, stem.2 = 8, stem.3 = 7...

do i = 1 to 10
  stem.i = 10 - i
end

Unlike a typical array, a tail (index) need not identify (be named) an integer value. For example, the following code is valid:

i = 'Monday'
stem.i = 2

A default value can be assigned to a stem via . but no tail.

stem. = 'Unknown'
stem.1 = 'USA'
stem.44 = 'UK'
stem.33 = 'France'

In this case stem.3, for example, evaluates to the default value, 'Unknown'.

The whole stem (including any default value) can be erased with the drop statement.

drop stem.

By convention (not part of the language) the compound stem.0 is often used to keep track of how many items are in a stem, for example a procedure to add a word to a list might be coded like this:

add_word: procedure expose dictionary.
  parse arg w
  n = dictionary.0 + 1
  dictionary.n = w
  dictionary.0 = n
return

A stem can have multiple tails. For example:

m = 'July'
d = 15
y = 2005
day.y.m.d = 'Friday'

Multiple numerical tail elements can be used to provide the effect of a multi-dimensional array.

Features similar the compound variable are found in other languages including associative arrays in AWK, hashes in Perl and Hashtables in Java, dynamic objects in Javascript. Most of these languages provide an mechanism to iterate over the keys (tails) of such a construct, but this is lacking in classic Rexx. Instead, it is necessary to store additional information. For example, the following procedure might be used to count each occurrence of a word.

add_word: procedure expose count. word_list
  parse arg w .
  count.w = count.w + 1 /* assume count. has been set to 0 */
  if count.w = 1 then word_list = word_list w
return

and then later:

do i = 1 to words(word_list)
  w = word(word_list,i)
  say w count.w
end

More recent Rexx variants, including Object REXX and ooRexx, provide a construct to iterate over the tails of a stem.

do i over stem.
  say i '-->' stem.i
end

Parse

The parse instruction provides string-handling via syntax:

parse [upper] origin [template]

where origin specifies the source:

• arg (arguments, at top level tail of command line)
• linein (standard input, e.g. keyboard)
• pull (Rexx data queue or standard input)
• source (info on how program was executed)
• value (an expression) with: the keyword with is required to indicate where the expression ends
• var (a variable)
• version (version/release number)

and template can be:

• list of variables
• A period to indicate a datum to be discarded
• column number delimiters
• literal delimiters

upper is optional; if specified, data will be converted to upper case before parsing.

Examples

Using a list of variables as template

myVar = "John Smith"
parse var myVar firstName lastName
say "First name is:" firstName
say "Last name is:" lastName

displays the following:

First name is: John
Last name is: Smith

Using a delimiter as template:

myVar = "Smith, John"
parse var myVar LastName "," FirstName
say "First name is:" firstName
say "Last name is:" lastName

also displays the following:

First name is: John
Last name is: Smith

Using column number delimiters:

myVar = "(202) 123-1234"
parse var MyVar 2 AreaCode 5 7 SubNumber
say "Area code is:" AreaCode
say "Subscriber number is:" SubNumber

displays the following:

Area code is: 202
Subscriber number is: 123-1234

A template can use a combination of variables, literal delimiters, and column number delimiters.

Interpret

The interpret instruction evaluates its argument and treats its value as a Rexx statement. Sometimes interpret is the clearest way to perform a task, but it is often used where clearer code is possible using, e.g., value().

Other uses of interpret are (decimal) arbitrary precision arithmetic (including fuzzy comparisons), use of the parse statement with programmatic templates, stemmed arrays, and sparse arrays.

/* demonstrate interupt with square(4) => 16 */
X = 'square'
interpret 'say' X || '(4) ; exit'
SQUARE: return arg(1)**2

This displays 16 and exits. Because variable contents are strings, including rational numbers with exponents and even entire programs, Rexx offers to interpret strings as evaluated expressions.

This feature could be used to pass functions as function parameters, such as passing SIN or COS to a procedure to calculate integrals.

The language offers only basic math functions like ABS, DIGITS, MAX, MIN, SIGN, RANDOM, and a complete set of hex plus binary conversions with bit operations. More complex functions like SIN were implemented from scratch or obtained from third party external libraries. Some external libraries, typically those implemented in traditional languages, did not support extended precision.

Later versions (non-classic) support CALL variable constructs. Together with the built-in function VALUE, CALL can be used in place of many cases of interpret. This is a classic program:

/* terminated by input "exit" or similar */
do forever ; interpret linein() ; end

A slightly more sophisticated "Rexx calculator":

X = 'input BYE to quit'
do until X = 'BYE' ; interpret 'say' X ; pull X ; end

PULL is shorthand for parse upper pull. Likewise, ARG is shorthand for parse upper arg.

The power of the interpret instruction had other uses. The Valour software package relied upon Rexx's interpretive ability to implement an OOP environment. Another use was found in an unreleased Westinghouse product called Time Machine that was able to fully recover following an otherwise fatal error.

Numeric

say digits() fuzz() form() /* => 9 0 SCIENTIFIC */
say 999999999+1 /* => 1.000000000E+9 */
numeric digits 10 /* only limited by available memory */
say 999999999+1 /* => 1000000000 */

say 0.9999999999=1 /* => 0 (false) */
numeric fuzz 3
say 0.99999999=1 /* => 1 (true) */
say 0.99999999==1 /* => 0 (false) */

say 100*123456789 /* => 1.23456789E+10 */
numeric form engineering
say 100*123456789 /* => 12.34567890E+9 */

say 53 // 7   /* => 4   (rest of division)*/

Calculate √2

numeric digits 50
n=2
r=1
do forever /* Newton's method */
  rr=(n/r+r)/2
  if r=rr then leave
  r=rr
end
say "sqrt" n ' = ' r

sqrt 2 = 1.414213562373095048801688724209698078569671875377

Calculate e

numeric digits 50
e=2.5
f=0.5
do n=3
  f=f/n
  ee=e+f
  if e=ee then leave
  e=ee
end
say "e =" e

e = 2.7182818284590452353602874713526624977572470936998

Error handling

The signal instruction configures the runtime to invoke a handler for a system condition if triggered. The following program prints a message when the user terminates (halts) it:

signal on halt;
do a = 1
  say a
  do 100000 /* a delay */
  end
end
halt:
say "The program was stopped by the user"
exit

Conditions

ERROR

Positive return code from a system command

FAILURE

Negative return code from a system command (e.g. command doesn't exist)

HALT

Abnormal termination

NOVALUE

A variable name was used but the variable is not defined

NOTREADY

Input or output error (e.g. read attempts beyond end of file)

SYNTAX

Invalid program syntax, or some other error condition

LOSTDIGITS

Significant digits are lost (ANSI Rexx, not in TRL second edition)

Handling

When a condition is handled (as configured via signal on), the condition can be analyzed via RC which contains the last error code and SIGL which contains the line number of the code that triggered the condition.

Beginning with Rexx version 4 conditions can get names, and there's a CALL ON construct – useful if external functions do not necessarily exist:

ChangeCodePage: procedure /* protect SIGNAL settings */
  signal on syntax name ChangeCodePage.Trap
return SysQueryProcessCodePage()
ChangeCodePage.Trap: return 1004 /* windows-1252 on OS/2 */

See also

• ISPF
• XEDIT
• Comparison of computer shells
• Comparison of programming languages

Further reading

• Callaway, Merrill. The ARexx Cookbook: A Tutorial Guide to the ARexx Language on the Commodore Amiga Personal Computer. Whitestone, 1992. ISBN 978-0963277305.
• Callaway, Merrill. The Rexx Cookbook: A Tutorial Guide to the Rexx Language in OS/2 & Warp on the IBM Personal Computer. Whitestone, 1995. ISBN 0-9632773-4-0.
• Cowlishaw, Michael. The Rexx Language: A Practical Approach to Programming. Prentice Hall, 1990. ISBN 0-13-780651-5.
• Cowlishaw, Michael. The NetRexx Language. Prentice Hall, 1997. ISBN 0-13-806332-X.
• Daney, Charles. Programming in REXX. McGraw-Hill, TX, 1990. ISBN 0-07-015305-1.
• Ender, Tom. Object-Oriented Programming With Rexx. John Wiley & Sons, 1997. ISBN 0-471-11844-3.
• Fosdick, Howard. Rexx Programmer's Reference. Wiley/Wrox, 2005. ISBN 0-7645-7996-7.
• Gargiulo, Gabriel. REXX with OS/2, TSO, & CMS Features. MVS Training, 1999 (third edition 2004). ISBN 1-892559-03-X.
• Goldberg, Gabriel and Smith, Philip H. The Rexx Handbook . McGraw-Hill, TX, 1992. ISBN 0-07-023682-8.
• Goran, Richard K. REXX Reference Summary Handbook. CFS Nevada, Inc.,1997. ISBN 0-9639854-3-4.
• IBM Redbooks. Implementing Rexx Support in Sdsf. Vervante, 2007. ISBN 0-7384-8914-X.
• Kiesel, Peter C. Rexx: Advanced Techniques for Programmers. McGraw-Hill, TX, 1992. ISBN 0-07-034600-3.
• Marco, Lou ISPF/REXX Development for Experienced Programmers. CBM Books, 1995. ISBN 1-878956-50-7
• O'Hara, Robert P. and Gomberg, David Roos. Modern Programming Using Rexx. Prentice Hall, 1988. ISBN 0-13-597329-5.
• Rudd, Anthony S. 'Practical Usage of TSO REXX'. CreateSpace, 2012. ISBN 978-1475097559.
• Schindler, William. Down to Earth Rexx. Perfect Niche Software, 2000. ISBN 0-9677590-0-5.

External links

• Mike Cowlishaw's home page
• REXX language page at IBM
• Rexx Language Association